I use Nix btw

.envrc

@@ -0,0 +1 @@
+use nix

.gitignore

@@ -1,3 +1,5 @@
 /target
 /db.sqlite3*
 /files
+/.direnv
+/result

Dockerfile

@@ -4,17 +4,18 @@ RUN apk add --no-cache musl-dev perl build-base zig
 RUN cargo install --locked cargo-zigbuild
 RUN rustup target add x86_64-unknown-linux-musl aarch64-unknown-linux-musl
 WORKDIR /app
-COPY Cargo.toml Cargo.lock .
+COPY Cargo.toml Cargo.lock ./
 COPY migration ./migration
 RUN mkdir src \
-  && echo "fn main() {}" > src/main.rs \
+    && echo "fn main() {}" > src/main.rs \
-  && cargo fetch \
+    && cargo fetch \
-  && cargo zigbuild --release --locked --target x86_64-unknown-linux-musl --target aarch64-unknown-linux-musl \
+    && cargo zigbuild --release --locked --target x86_64-unknown-linux-musl --target aarch64-unknown-linux-musl \
-  && rm src/main.rs
+    && rm src/main.rs
 COPY static ./static
 COPY templates ./templates
 COPY src ./src
-RUN cargo zigbuild --release --locked --target x86_64-unknown-linux-musl --target aarch64-unknown-linux-musl
+RUN touch src/main.rs \
+    && cargo zigbuild --release --locked --target x86_64-unknown-linux-musl --target aarch64-unknown-linux-musl
 
 FROM --platform=$BUILDPLATFORM scratch AS binary
 COPY --from=builder /app/target/x86_64-unknown-linux-musl/release/samey /samey-linux-amd64

LICENSE

@@ -1,4 +1,4 @@
-Copyright (c) 2025 Bad Manners
+Copyright (c) 2025-2026 Bad Manners
 
 Permission is hereby granted, free of charge, to any
 person obtaining a copy of this software and associated

default.nix

@@ -0,0 +1,111 @@
+let
+  inherit (import ./npins)
+    nixpkgs
+    rust-overlay
+    ;
+  pkgs = import nixpkgs {
+    overlays = [ (import rust-overlay) ];
+  };
+  inherit (pkgs) lib stdenv;
+
+  # Options for your package
+  pname = "samey";
+  version = "0.1.0";
+  docker-image = "badmanners/samey";
+  cargo-deps-hash = "sha256-oiz2a6Vip199saU/s/sBn/3Cl0eJaSltN3n1uPETHGk=";
+  src = lib.fileset.toSource {
+    root = ./.;
+    fileset = lib.fileset.unions [
+      ./Cargo.toml
+      ./Cargo.lock
+      ./src
+      ./migration/Cargo.toml
+      ./migration/src
+      ./static
+      ./templates
+    ];
+  };
+
+  rust-bin = pkgs.rust-bin.stable.latest.default.override {
+    targets = [
+      "x86_64-unknown-linux-gnu"
+      "aarch64-unknown-linux-gnu"
+    ];
+  };
+
+  mkRustPkg =
+    target:
+    stdenv.mkDerivation {
+      inherit
+        pname
+        version
+        src
+        ;
+
+      cargoDeps = pkgs.rustPlatform.fetchCargoVendor {
+        inherit src;
+        hash = cargo-deps-hash;
+      };
+
+      nativeBuildInputs = [
+        pkgs.rustPlatform.cargoSetupHook
+        pkgs.zig
+        rust-bin
+      ];
+
+      buildPhase = ''
+        export HOME=$(mktemp -d)
+        ${pkgs.cargo-zigbuild}/bin/cargo-zigbuild zigbuild --release --target ${target}
+      '';
+
+      installPhase = ''
+        mkdir -p $out/bin
+        cp ./target/${target}/release/${pname} $out/bin/
+      '';
+    };
+
+  amd64 = {
+    system = "x86_64-linux";
+    pkgs = import nixpkgs {
+      localSystem = "x86_64-linux";
+    };
+    tag = "latest-amd64";
+    target = "x86_64-unknown-linux-gnu";
+  };
+
+  arm64 = {
+    system = "aarch64-linux";
+    pkgs = import nixpkgs {
+      localSystem = "aarch64-linux";
+    };
+    tag = "latest-arm64";
+    target = "aarch64-unknown-linux-gnu";
+  };
+
+  mkDocker =
+    targetAttrs:
+    let
+      pkgs-cross =
+        if targetAttrs.system == builtins.currentSystem then
+          pkgs
+        else
+          (import nixpkgs {
+            crossSystem = targetAttrs.system;
+          });
+      rust-package = mkRustPkg targetAttrs.target;
+    in
+    pkgs-cross.dockerTools.buildLayeredImage {
+      name = docker-image;
+      inherit (targetAttrs) tag;
+      contents = [
+        targetAttrs.pkgs.ffmpeg-headless
+      ];
+      config.Entrypoint = [
+        "${rust-package}/bin/${pname}"
+      ];
+    };
+in
+{
+  docker-amd64 = mkDocker amd64;
+  docker-arm64 = mkDocker arm64;
+}

npins/default.nix

@@ -0,0 +1,249 @@
+/*
+  This file is provided under the MIT licence:
+
+  Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the “Software”), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
+
+  The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
+
+  THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
+*/
+# Generated by npins. Do not modify; will be overwritten regularly
+let
+  # Backwards-compatibly make something that previously didn't take any arguments take some
+  # The function must return an attrset, and will unfortunately be eagerly evaluated
+  # Same thing, but it catches eval errors on the default argument so that one may still call it with other arguments
+  mkFunctor =
+    fn:
+    let
+      e = builtins.tryEval (fn { });
+    in
+    (if e.success then e.value else { error = fn { }; }) // { __functor = _self: fn; };
+
+  # https://github.com/NixOS/nixpkgs/blob/0258808f5744ca980b9a1f24fe0b1e6f0fecee9c/lib/lists.nix#L295
+  range =
+    first: last: if first > last then [ ] else builtins.genList (n: first + n) (last - first + 1);
+
+  # https://github.com/NixOS/nixpkgs/blob/0258808f5744ca980b9a1f24fe0b1e6f0fecee9c/lib/strings.nix#L257
+  stringToCharacters = s: map (p: builtins.substring p 1 s) (range 0 (builtins.stringLength s - 1));
+
+  # https://github.com/NixOS/nixpkgs/blob/0258808f5744ca980b9a1f24fe0b1e6f0fecee9c/lib/strings.nix#L269
+  stringAsChars = f: s: concatStrings (map f (stringToCharacters s));
+  concatStrings = builtins.concatStringsSep "";
+
+  # If the environment variable NPINS_OVERRIDE_${name} is set, then use
+  # the path directly as opposed to the fetched source.
+  # (Taken from Niv for compatibility)
+  mayOverride =
+    name: path:
+    let
+      envVarName = "NPINS_OVERRIDE_${saneName}";
+      saneName = stringAsChars (c: if (builtins.match "[a-zA-Z0-9]" c) == null then "_" else c) name;
+      ersatz = builtins.getEnv envVarName;
+    in
+    if ersatz == "" then
+      path
+    else
+      # this turns the string into an actual Nix path (for both absolute and
+      # relative paths)
+      builtins.trace "Overriding path of \"${name}\" with \"${ersatz}\" due to set \"${envVarName}\"" (
+        if builtins.substring 0 1 ersatz == "/" then
+          /. + ersatz
+        else
+          /. + builtins.getEnv "PWD" + "/${ersatz}"
+      );
+
+  mkSource =
+    name: spec:
+    {
+      pkgs ? null,
+    }:
+    assert spec ? type;
+    let
+      # Unify across builtin and pkgs fetchers.
+      # `fetchGit` requires a wrapper because of slight API differences.
+      fetchers =
+        if pkgs == null then
+          {
+            inherit (builtins) fetchTarball fetchurl;
+            # For some fucking reason, fetchGit has a different signature than the other builtin fetchers …
+            fetchGit = args: (builtins.fetchGit args).outPath;
+          }
+        else
+          {
+            fetchTarball =
+              {
+                url,
+                sha256,
+              }:
+              pkgs.fetchzip {
+                inherit url sha256;
+                extension = "tar";
+              };
+            inherit (pkgs) fetchurl;
+            fetchGit =
+              {
+                url,
+                submodules,
+                rev,
+                name,
+                narHash,
+              }:
+              pkgs.fetchgit {
+                inherit url rev name;
+                fetchSubmodules = submodules;
+                hash = narHash;
+              };
+          };
+
+      # Dispatch to the correct code path based on the type
+      path =
+        if spec.type == "Git" then
+          mkGitSource fetchers spec
+        else if spec.type == "GitRelease" then
+          mkGitSource fetchers spec
+        else if spec.type == "PyPi" then
+          mkPyPiSource fetchers spec
+        else if spec.type == "Channel" then
+          mkChannelSource fetchers spec
+        else if spec.type == "Tarball" then
+          mkTarballSource fetchers spec
+        else if spec.type == "Container" then
+          mkContainerSource pkgs spec
+        else
+          builtins.throw "Unknown source type ${spec.type}";
+    in
+    spec // { outPath = mayOverride name path; };
+
+  mkGitSource =
+    {
+      fetchTarball,
+      fetchGit,
+      ...
+    }:
+    {
+      repository,
+      revision,
+      url ? null,
+      submodules,
+      hash,
+      ...
+    }:
+    assert repository ? type;
+    # At the moment, either it is a plain git repository (which has an url), or it is a GitHub/GitLab repository
+    # In the latter case, there we will always be an url to the tarball
+    if url != null && !submodules then
+      fetchTarball {
+        inherit url;
+        sha256 = hash;
+      }
+    else
+      let
+        url =
+          if repository.type == "Git" then
+            repository.url
+          else if repository.type == "GitHub" then
+            "https://github.com/${repository.owner}/${repository.repo}.git"
+          else if repository.type == "GitLab" then
+            "${repository.server}/${repository.repo_path}.git"
+          else if repository.type == "Forgejo" then
+            "${repository.server}/${repository.owner}/${repository.repo}.git"
+          else
+            throw "Unrecognized repository type ${repository.type}";
+        urlToName =
+          url: rev:
+          let
+            matched = builtins.match "^.*/([^/]*)(\\.git)?$" url;
+
+            short = builtins.substring 0 7 rev;
+
+            appendShort = if (builtins.match "[a-f0-9]*" rev) != null then "-${short}" else "";
+          in
+          "${if matched == null then "source" else builtins.head matched}${appendShort}";
+        name = urlToName url revision;
+      in
+      fetchGit {
+        rev = revision;
+        narHash = hash;
+
+        inherit name submodules url;
+      };
+
+  mkPyPiSource =
+    { fetchurl, ... }:
+    {
+      url,
+      hash,
+      ...
+    }:
+    fetchurl {
+      inherit url;
+      sha256 = hash;
+    };
+
+  mkChannelSource =
+    { fetchTarball, ... }:
+    {
+      url,
+      hash,
+      ...
+    }:
+    fetchTarball {
+      inherit url;
+      sha256 = hash;
+    };
+
+  mkTarballSource =
+    { fetchTarball, ... }:
+    {
+      url,
+      locked_url ? url,
+      hash,
+      ...
+    }:
+    fetchTarball {
+      url = locked_url;
+      sha256 = hash;
+    };
+
+  mkContainerSource =
+    pkgs:
+    {
+      image_name,
+      image_tag,
+      image_digest,
+      ...
+    }:
+    if pkgs == null then
+      builtins.throw "container sources require passing in a Nixpkgs value: https://github.com/andir/npins/blob/master/README.md#using-the-nixpkgs-fetchers"
+    else
+      pkgs.dockerTools.pullImage {
+        imageName = image_name;
+        imageDigest = image_digest;
+        finalImageTag = image_tag;
+      };
+in
+mkFunctor (
+  {
+    input ? ./sources.json,
+  }:
+  let
+    data =
+      if builtins.isPath input then
+        # while `readFile` will throw an error anyways if the path doesn't exist,
+        # we still need to check beforehand because *our* error can be caught but not the one from the builtin
+        # *piegames sighs*
+        if builtins.pathExists input then
+          builtins.fromJSON (builtins.readFile input)
+        else
+          throw "Input path ${toString input} does not exist"
+      else if builtins.isAttrs input then
+        input
+      else
+        throw "Unsupported input type ${builtins.typeOf input}, must be a path or an attrset";
+    version = data.version;
+  in
+  if version == 7 then
+    builtins.mapAttrs (name: spec: mkFunctor (mkSource name spec)) data.pins
+  else
+    throw "Unsupported format version ${toString version} in sources.json. Try running `npins upgrade`"
+)

npins/sources.json

@@ -0,0 +1,24 @@
+{
+  "pins": {
+    "nixpkgs": {
+      "type": "Channel",
+      "name": "nixpkgs-unstable",
+      "url": "https://releases.nixos.org/nixpkgs/nixpkgs-26.05pre926176.3fbab70c6e69/nixexprs.tar.xz",
+      "hash": "sha256-+Wh8S0NwhQWHfdzHCe3mLKwAxQJ2cHe7b9PBcFWSUWg="
+    },
+    "rust-overlay": {
+      "type": "Git",
+      "repository": {
+        "type": "GitHub",
+        "owner": "oxalica",
+        "repo": "rust-overlay"
+      },
+      "branch": "master",
+      "submodules": false,
+      "revision": "af69e497567a5945a64057717bc9b17c8478097e",
+      "url": "https://github.com/oxalica/rust-overlay/archive/af69e497567a5945a64057717bc9b17c8478097e.tar.gz",
+      "hash": "sha256-nkpIe3zkpeoFuOl8xBpexulECsHLQ9Ljg1gW3bPCjSI="
+    }
+  },
+  "version": 7
+}

shell.nix

@@ -0,0 +1,17 @@
+let
+  inherit (import ./npins)
+    nixpkgs
+    rust-overlay
+    ;
+  pkgs = import nixpkgs {
+    overlays = [ (import rust-overlay) ];
+  };
+in
+pkgs.mkShell {
+  packages = [
+    pkgs.bacon
+    pkgs.just
+    pkgs.rust-bin.stable.latest.default
+    pkgs.sea-orm-cli
+  ];
+}